Re: How to select list of attributes in PROC SQL by using macro

Toby,

There is no harm in illustrating good design principles when
giving the answer. Thus isolate the problem.

%macro mklist ( pref=A_ , from = 1 , to = 1 , sep = %str(,)) ;
%local i list ;
%do i = &from %to &to ;
%let list = &list&sep &pref&i ;
%end ;
%substr(&list,2)
%mend ;

Then Mark could use in many different SQL situations.

proc sql;
select %mklist(pref=a_,to=20) from table_name;
quit;

Ian Whitlock
=================
Date: Fri, 17 Jun 2005 02:39:16 +0000
Reply-To: toby dunn <tobydunn@HOTMAIL.COM>
Sender: "SAS(r) Discussion"
From: toby dunn <tobydunn@HOTMAIL.COM>
Subject: Re: How to select list of attributes in PROC SQL by
using macro
variables
Comments: To: joystar.jin@GMAIL.COM
In-Reply-To:
<1118969589.523359.142670@g43g2000cwa.googlegroups .com>
Content-Type: text/plain; format=flowed
Mark ,
For you viewing entertainment:
%macro alpha ;
%local var_list i ;
data one ;
array test (5) a_1-a_5 ;
do i = 1 to 5 ;
test(i) = i ;
output ;
end ;
run ;
%do i = 1 %to 4 ;
%let var_list = &var_list A_&i , ;
%end ;
proc sql ;
select &var_list i
from one ;
quit ;
%mend ;
%alpha

Toby Dunn


From: Mark <joystar.jin@GMAIL.COM>
Reply-To: Mark <joystar.jin@GMAIL.COM>
To: SAS-L@LISTSERV.UGA.EDU
Subject: How to select list of attributes in PROC SQL by using
macro
variables
Date: Thu, 16 Jun 2005 17:53:09 -0700
I need to use PROC SQL to select a list of variables in my macro
program.
The list of variables are in the form of
A1, A2,.....,A20
I need to refer to them by using following macro variable as:
A_&index1 - A_&index2
where index1 and index2 are macro variables.
Can I do following in PROC SQL?
proc sql;
select A_&index1 - A_&index2 from table_name;
quit;
Otherwise, is there a way to do it in SAS?
Thanks,